设为首页收藏本站我不能发帖?请关注天意的微信公众号
天意U盘维护系统讨论区»论坛 › 软件硬件交流 › 精品软件共享 › NSIS练习之作-精选手写字体（附NSIS教程电子书）
1234下一页
返回列表 发新帖
楼主: 天意

NSIS练习之作-精选手写字体（附NSIS教程电子书）

  [复制链接]
发表于 2011-10-21 20:40:46 | 显示全部楼层
没用过·······谢谢分享········
回复 支持 反对

使用道具 举报

发表于 2011-11-18 03:05:55 | 显示全部楼层
支持天意，谢谢分享
回复 支持 反对

使用道具 举报

AMNZ
发表于 2011-11-19 02:01:42 | 显示全部楼层
学无止境  呵呵
回复 支持 反对

使用道具 举报

csf4
发表于 2011-11-20 15:41:25 | 显示全部楼层
一定是好东西！
回复 支持 反对

使用道具 举报

发表于 2012-8-23 14:06:49 | 显示全部楼层
天意老师 能不能给我 天意U盘维护系统 3.0网络增强版 的源代码啊
回复 支持 反对

使用道具 举报

 楼主| 发表于 2012-8-23 15:24:00 | 显示全部楼层
_ㄨ.Ian 发表于 2012-8-23 14:06
天意老师 能不能给我 天意U盘维护系统 3.0网络增强版 的源代码啊
  1. ##这是一个可以安装fba包的u盘启动安装器源码，
  2. ##资源包src里面的ty.fba是一个空文件，请用自己的fba包替换。
  3. ##=====================================
  4. ##本源码由teasiu@163.com创建。请保留此信息。
  5. ##=====================================
  6. !define NAME "天意U盘维护系统"
  7. !define DISTRO "天意U盘维护系统"
  8. !define FILENAME "天意U盘维护系统"
  9. !define VERSION "网络增强V2012版"
  10. !define MUI_ICON "AUTORUN.ICO"
  11. RequestExecutionLevel highest
  12. SetCompressor LZMA
  13. CRCCheck On
  14. XPStyle on
  15. ShowInstDetails show
  16. BrandingText "天意U盘维护系统安装器"
  17. CompletedText "安装结束，欢迎使用和收藏本工具! "
  18. InstallButtonText "安 装"

  20. Name "${NAME} ${VERSION}"
  21. OutFile "${FILENAME} ${VERSION}.exe"

  23. !include "nsDialogs.nsh"
  24. !include "MUI2.nsh"
  25. !include "FileFunc.nsh"
  26. !include "WordFunc.nsh" ;DriveList
  27. ; Interface settings
  28. !define MUI_HEADERIMAGE
  29. !define MUI_HEADERIMAGE_BITMAP "usb-logo.bmp"
  30. !define MUI_HEADERIMAGE_BITMAP_NOSTRETCH
  31. !define MUI_HEADERIMAGE_RIGHT

  33. ; Drive page
  34. Var Dialog
  35. Var DestDriveTxt
  36. Var DestDrive
  37. Var DestDisk
  38. Var LabelDrivePageText
  39. Var LabelDriveSelect
  40. Var AllDriveOption
  41. Var DisplayAll
  42. Var Format
  43. Var FormatMe
  44. Var Hddmode
  45. Var Zipmode
  46. Var HddmodeMe
  47. Var ZipmodeMe
  48. Var Warning
  49. Var Soft
  50. Var Link
  51. Var Links
  52. Var Image
  53. Var hImage
  54. Var size


  57. #Page custom SetCustom LeaveCustom
  58. Page custom drivePage


  61. !define MUI_INSTFILESPAGE_COLORS "00FF00 000000"
  62. ; Instfiles page
  63. !define MUI_TEXT_INSTALLING_TITLE $(Install_Title)
  64. !define MUI_TEXT_INSTALLING_SUBTITLE $(Install_SubTitle)
  65. !define MUI_TEXT_FINISH_SUBTITLE $(Install_Finish_Sucess)
  66. !insertmacro MUI_PAGE_INSTFILES

  68. ; Language files
  69. !insertmacro MUI_LANGUAGE "SimpChinese"
  70. LangString DrivePage_Title ${LANG_SIMPCHINESE} "【天意作品】天意U盘维护系统安装器"
  71. LangString DrivePage_Title2 ${LANG_SIMPCHINESE} "先插入您的U盘或移动硬盘，然后再打开本软件进行安装。"
  72. LangString DrivePage_Text ${LANG_SIMPCHINESE} "本工具将使您的USB设备完美启动。"
  73. LangString DrivePage_Input ${LANG_SIMPCHINESE} "第一步：点击下拉菜单选择磁盘"
  74. LangString Soft_Text ${LANG_SIMPCHINESE} "第二步：选择USB设备启动引导模式。必选。"
  75. LangString WarningPage_Text ${LANG_SIMPCHINESE} "注意：请确保U盘资料已备份。原资料将被完全覆写并不可恢复！"
  76. LangString Install_Title ${LANG_SIMPCHINESE} "安装中 ${DISTRO}"
  77. LangString Install_SubTitle ${LANG_SIMPCHINESE} "请稍候 ${NAME} 安装 ${DISTRO} 到 $DestDisk"
  78. LangString Install_Finish_Sucess ${LANG_SIMPCHINESE} "$\t ${NAME} 已经完成安装${DISTRO}到$DestDisk"

  80. Function .onInit
  81. InitPluginsDir
  82. File /oname=$PLUGINSDIR\ad.bmp "ad.bmp" ; 嵌入bmp位图以便后面调用
  83. FunctionEnd

  85. Function drivePage
  86. !insertmacro MUI_HEADER_TEXT $(DrivePage_Title) $(DrivePage_Title2)
  87. nsDialogs::Create 1018
  88. Pop $Dialog
  89. ${If} $DestDrive == ""
  90. GetDlgItem $6 $HWNDPARENT 1 ; Get next control handle
  91. EnableWindow $6 0 ; disable next
  92. ${EndIf}
  93. ;创建bmp位图
  94. ${NSD_CreateBitmap} 78% 0 20% 100% ""
  95. Pop $Image
  96. ${NSD_SetImage} $Image $PLUGINSDIR\ad.bmp $hImage

  98. ${NSD_CreateLabel} 0 0 70% 30 $(DrivePage_Text)
  99. Pop $LabelDrivePageText
  100. ${NSD_CreateLabel} 0 20 70% 25 $(DrivePage_Input)
  101. Pop $LabelDriveSelect
  102. SetCtlColors $LabelDriveSelect /Branding 0000BD

  104. ${NSD_CreateCheckBox} 33% 43 45% 14 "显示全部驱动盘 (慎用)"
  105. Pop $AllDriveOption
  106. ${NSD_OnClick} $AllDriveOption ListAllDrives
  107. ${NSD_CreateDroplist} 0 40 30% 25 ""
  108. Pop $DestDriveTxt
  109. Call ListAllDrives
  110. ${NSD_OnChange} $DestDriveTxt db_select.onchange
  111. ${If} $DestDrive != ""
  112. ${NSD_CB_SelectString} $DestDriveTxt $DestDrive
  113. ${EndIf}

  115. ; Add Help Link
  116. ${NSD_CreateLink} 84% 192 15% 14 "软件更新" ; 创建一个链接地址 84%代表位置横坐标,190代表位置纵坐标,15%代表内容横坐标,14代表内容纵坐标
  117. Pop $Link
  118. ${NSD_OnClick} $Link onClickMyLink
  119. ; Format Drive Option
  120. ${NSD_CreateButton} 33% 64 32% 22 "(可选)格式化回收空间"
  121. Pop $Format
  122. ${NSD_OnClick} $Format FormatIt
  123. ; Soft Label
  124. ${NSD_CreateLabel} 0 100 70% 15 $(Soft_Text) ;软件内容 0代表位置横坐标,70代表位置纵坐标,70%代表内容横坐标,15代表内容纵坐标
  125. Pop $Soft
  126. SetCtlColors $Soft /Branding 0000BD

  128. ; 磁盘启动模式选项
  129. ${NSD_CreateCheckBox} 0 120 36% 15 "HDD启动模式."
  130. Pop $Hddmode
  131. ${NSD_Check} $Hddmode
  132. ${NSD_OnClick} $Hddmode HddmodeIt

  134. ${NSD_CreateCheckBox} 38% 120 36% 15 "ZIP启动模式."
  135. Pop $Zipmode
  136. ${NSD_OnClick} $Zipmode ZipmodeIt

  138. ; Warning Label
  139. ${NSD_CreateLabel} 0 190 80% 14 $(WarningPage_Text)
  140. Pop $Warning
  141. EnableWindow $Format 0
  142. EnableWindow $Hddmode 0
  143. EnableWindow $Zipmode 0
  144. ShowWindow $Warning 0
  145. GetDlgItem $6 $HWNDPARENT 3
  146. ShowWindow $6 0 ; Disable Back
  147. nsDialogs::Show
  148. ${NSD_FreeImage} $hImage
  149. FunctionEnd

  151. Function ListAllDrives ; Set to Display All Drives
  152. SendMessage $DestDriveTxt ${CB_RESETCONTENT} 0 0
  153. ${NSD_GetState} $AllDriveOption $DisplayAll
  154. ${If} $DisplayAll == ${BST_CHECKED}
  155. ${NSD_Check} $AllDriveOption
  156. ${NSD_SetText} $AllDriveOption "现在显示所有驱动盘 (小心)"
  157. ${GetDrives} "ALL" DrivesList ; All Drives Listed
  158. ${ElseIf} $DisplayAll == ${BST_UNCHECKED}
  159. ${NSD_Uncheck} $AllDriveOption
  160. ${NSD_SetText} $AllDriveOption "显示所有驱动盘 (慎用)"
  161. ${GetDrives} "FDD" DrivesList ; FDD+HDD reduce to FDD for removable media only
  162. ${EndIf}
  163. FunctionEnd

  165. Function onClickMyLink
  166. Pop $Links ; pop something to prevent corruption
  167. ExecShell "open" "http://www.winpe.cc"
  168. FunctionEnd


  171. Function db_select.onchange
  172. Pop $DestDriveTxt
  173. ${NSD_GetText} $DestDriveTxt $0
  174. StrCpy $DestDrive "$0"
  175. StrCpy $DestDisk "$DestDrive" -1
  176. GetDlgItem $6 $HWNDPARENT 1 ; Get "Next" control handle
  177. EnableWindow $6 1 ; enable "Next" control
  178. EnableWindow $Format 1
  179. EnableWindow $Hddmode 1
  180. EnableWindow $Zipmode 1
  181. ShowWindow $Warning 1
  182. SetCtlColors $Warning /Branding FF0000
  183. Call HddmodeIt
  184. Call ZipmodeIt
  185. FunctionEnd

  187. Function DrivesList ; 磁盘列表，表示形式为盘符CDE等
  188. SendMessage $DestDriveTxt ${CB_ADDSTRING} 0 "STR:$9"
  189. Push 1
  190. FunctionEnd

  192. ;下面2个方程的意思是:无论用户怎么点击，都必须要选中一个
  193. Function HddmodeIt
  194. ${NSD_GetState} $Hddmode $HddmodeMe

  196. ${If} $HddmodeMe == ${BST_CHECKED}
  197. ${NSD_Check} $Hddmode
  198. StrCpy $HddmodeMe "Yes"
  199. ${NSD_SetText} $Hddmode "(已选)HDD启动模式"
  200. ${NSD_Uncheck} $Zipmode
  201. StrCpy $ZipmodeMe "No"
  202. ${NSD_SetText} $Zipmode "ZIP启动模式"

  204. ${ElseIf} $HddmodeMe == ${BST_UNCHECKED}
  205. ${NSD_Uncheck} $Hddmode
  206. StrCpy $HddmodeMe "No"
  207. ${NSD_SetText} $Hddmode "HDD启动模式"
  208. ${NSD_Check} $Zipmode
  209. StrCpy $ZipmodeMe "Yes"
  210. ${NSD_SetText} $Zipmode "(已选)ZIP启动模式"
  211. ${EndIf}
  212. FunctionEnd

  214. Function ZipmodeIt ; Set Format Option
  215. ${NSD_GetState} $Zipmode $ZipmodeMe
  216. ${If} $ZipmodeMe == ${BST_CHECKED}
  217. ${NSD_Check} $Zipmode
  218. StrCpy $ZipmodeMe "Yes"
  219. ${NSD_SetText} $Zipmode "(已选)ZIP启动模式"
  220. ${NSD_Uncheck} $Hddmode
  221. StrCpy $HddmodeMe "No"
  222. ${NSD_SetText} $Hddmode "HDD启动模式"
  223. ${ElseIf} $ZipmodeMe == ${BST_UNCHECKED}
  224. ${NSD_Uncheck} $Zipmode
  225. StrCpy $ZipmodeMe "No"
  226. ${NSD_SetText} $Zipmode "ZIP启动模式"
  227. ${NSD_Check} $Hddmode
  228. StrCpy $HddmodeMe "Yes"
  229. ${NSD_SetText} $Hddmode "(已选)HDD启动模式"
  230. ${EndIf}
  231. FunctionEnd

  233. Function FormatIt ; Set Format Option这里增加询问框，更加人性化
  234. Pop $FormatMe
  235. MessageBox MB_YESNO "格式化U盘可以取回全部空间，继续吗？" IDYES true IDNO false
  236. true:
  237. Goto next
  238. false:
  239. MessageBox MB_OK|MB_ICONSTOP "不格式化，退出"
  240. Abort
  241. next:
  242. MessageBox MB_YESNO "真的格式化吗？(请确保您的U盘资料已经备份,格式化将擦除U盘资料且不可恢复)" /SD IDYES IDNO false2
  243. Goto next2
  244. false2:
  245. MessageBox MB_OK|MB_ICONSTOP "不格式化，退出"
  246. Abort
  247. next2:
  248. InitPluginsDir
  249. File /oname=$PLUGINSDIR\fbinst.exe "src\fbinst.exe" ;调用一下src文件夹里面的fbinst.exe用于格式化
  250. nsExec::ExecToLog '"cmd" /c "echo y|$PLUGINSDIR\fbinst $DestDisk format --raw --force --fat32"'
  251. MessageBox MB_OK "格式化完成，恢复U盘全部空间。"
  252. FunctionEnd

  254. Function InstallEYes
  255. InitPluginsDir
  256. SetOutPath "$PLUGINSDIR"
  257. File /r "src\*.*" ;文件夹src里面必须包含2个文件,fbinst.exe和你的fba包,在这个例子里名字为ty.fba,下面要相对应名字
  258. ${GetSize} "$PLUGINSDIR" "/M=ty.fba /S=0M /G=0" $0 $1 $2
  259. StrCpy $size "$0"
  260. DetailPrint "fba包大小为$sizeMB"
  261. ${If} $HddmodeMe == "Yes"
  262. DetailPrint "创建HDD模式的引导和复制天意U盘维护系统到 $DestDisk, 请稍候"
  263. ;下面这段请根据您的fba包大小来填写UD扩展分区的大小extended ?m,UD主分区默认大小是8m,否则会出现安装错误。
  264. ;fba包目前使用fbinstool工具比较方便，假如你很掌握fbinst命令，也完全可以使用命令在这里创建fba包然后安装它,写起来比较复杂。
  265. nsExec::ExecToLog '"cmd" /c "echo y|$PLUGINSDIR\fbinst $DestDisk format --extended $sizeM --force --align --primary 8m --archive $PLUGINSDIR\ty.fba"'
  266. DetailPrint "天意U盘维护系统已经安装到$DestDisk的隐藏区占 $size MB + 8 MB"
  267. ${ElseIf} $ZipmodeMe == "Yes"
  268. DetailPrint "创建Zip模式的引导和复制天意U盘维护系统到 $DestDisk, 请稍候"
  269. nsExec::ExecToLog '"cmd" /c "echo y|$PLUGINSDIR\fbinst $DestDisk format --extended $sizeM --force --zip --align --primary 8m --archive $PLUGINSDIR\ty.fba"'
  270. DetailPrint "天意U盘维护系统zip模式已经安装到$DestDisk的隐藏区占 $size MB + 8 MB"
  271. ${EndIf}
  272. FunctionEnd

  274. Section "Install" main
  275. Call InstallEYes ;指令安装进程程式
  276. nsExec::ExecToLog '"cmd" /c "echo y|$PLUGINSDIR\fbinst $DestDisk pack"' ;安装完成后整理碎片
  277. SectionEnd
复制代码
回复 支持 反对

使用道具 举报

发表于 2012-8-24 14:59:57 | 显示全部楼层
谢谢天意老师
回复 支持 反对

使用道具 举报

发表于 2014-2-10 20:21:23 | 显示全部楼层
不错啊 谢谢老大分享
回复 支持 反对

使用道具 举报

发表于 2014-2-22 14:56:22 | 显示全部楼层
学习来了，下载下
回复 支持 反对

使用道具 举报

下一页 »
1234下一页
返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

小黑屋|手机版|Archiver|天意U盘维护系统 ( 鄂ICP备2020017155号 )

GMT+8, 2024-5-8 20:36 , Processed in 0.072545 second(s), 13 queries .

Powered by Discuz! X3.4

© 2001-2023 Comsenz Inc.

快速回复 返回顶部 返回列表